Pro batch_readnoise,dirlist, outps=outps, skipline=skipline, minexp=minexp

	; NAME:
	;      pro batch_readnoise.pro
	;
	; PURPOSE:
	;	This program is a batch procedure for readnoise_reduce.pro
    ;
	; CALLING SEQUENCE:
	;	batch_readnoise,dirlist [,/outps [,skipline]]
	;
	; INPUTS:
	;	dirlist			file name for file containing list of input directories
    ;	outps			switch to turn on PostScript output
	;
	; KEYWORD PARAMETERS:
	;      outps - Write postscript output
	;	   skipline		number of lines to skip when reading input directory list, defaults to 0

	;
	; EXAMPLE
	;      Run batch_darkcurrent to reduce results from several latent experiments. Make PostScript output
	;      batch_readnoise, filelist, /outps
	;
	; REFERENCE:
	;
	;
	; MODIFICATION HISTORY:
	;       Written by:  E. Morse, IDTL, April 10, 2003
    ;
    ;		Ernie Morse, IDTL, April 24, 2003
    ;		Added minexp keyword to allow for doing min-time (continuous read) read noise
	;-

	; Set directory string according to handle UNIX and Windows

	if (!version.os_family eq 'unix') then begin
		slashstring='/'
	endif else begin
        slashstring='\'
    endelse

    ; Set default file list
	if (not (keyword_set(dirlist))) then dirlist='batch_readnoise_dirlist.txt'

    ; Set defaults
    if (not keyword_set(outps)) then outps = 0  			; Default does not write PostScript
    if (not keyword_set(skipline)) then skipline=0
    if (not keyword_set(minexp)) then minexp = 0

	; read in list of directories
	  readcol, dirlist, datadirs, x1,x2,y1,y2, saref, maref, format='(A,I,I,I,I,I,I)', $
	           skipline=skipline

	; process data in each directory
	for i=0,n_elements(datadirs)-1 do begin
		; add a slash to the directory names if the last character is not one.
		if (strlen(datadirs(i)) ne strpos(datadirs(i),slashstring,/reverse_search)+1) then datadirs(i)=datadirs(i)+slashstring

		print,'Processing data in directory '+datadirs(i)

		;call darkcurrent_reduce--the directory list also contains the input parameters to use
  		readnoise_reduce, datadirs[i], outdir=datadirs[i]+'ReadNoise_Results', $
  	                    region=[x1[i],x2[i],y1[i],y2[i]], sa_refcor=saref[i], $
  	                    ma_refcor=maref[i], minexp=minexp

	endfor

End